{curl 6.0, 7.0 applet}
{set-document-properties font-size = 10pt}

{title Validate Always}

{doc-next
    {purpose A {docref MessageDialog} that can show one or more
        messages.
    }
}
{define-class public open MultiMessageDialog {inherits MessageDialog}

  field private mdpending?:bool = false
  field private results:ValidationResults = {ValidationResults}

  {doc-next
    {purpose Construct a {docref MultiMessageDialog} object.
    }
    {parameter title, The title to be used when a dialog is shown.
        If this is null a default title is used.
    }
    {parameter ..., Rest arguments are used to initialize this object,
        which will be placed within a dialog when shown.
    }
  }
  {constructor public {default
                          title:#String = null,
                          ...
                      }
    {construct-super title = title, {splice ...}}
  }

  {method public open {clear}:void
    {if not self.mdpending? then
        {self.results.clear}
    }
  }

  {method public open {show-results
                          results:ValidationResults
                      }:void
    {if {self.has-message? results} and not self.mdpending? then
        set self.mdpending? = true
        {self.add-internal replace? = true, {self.render-results results}}
        {after 0s do
            {popup-message title = self.title, self}
            set self.mdpending? = false
        }
    }
  }

  {method public open {show 
                          vc:ValidationComplete, 
                          target:ActiveTraversor
                      }:void
    {self.show-colors target}
    {if not vc.current? then {return}}
    let display?:bool = 
        not vc.consumed? and vc.display? and not vc.partial? 
        and not self.mdpending?
    {vc.consume}

    {if-non-null result = target.validation-result then
        {if-non-null message = result.message then
            {if self.mdpending? then
                {self.results.append result}
             else
                {self.results.clear}
                {self.results.append result}
            }
            {if display? then
                set self.mdpending? = true
                set self.color = self.message-color
                {after 0s do
                    {if {self.has-message? self.results} then
                        {self.add-internal replace? = true, 
                            {self.render-results self.results}}
                        {popup-message title = self.title, self}
                    }
                    set self.mdpending? = false
                }
            }
        }
    }
  }
}


{define-class package MyValidator {inherits Validator}
  {method public open {validate-value
                          controller:ValidationController,
                          target:ValueControl,
                          partial?:bool
                      }:#Visual

    {type-switch target.value-as-any
     case sv:StringInterface do
        {if target.valid? then
        {if (controller.required? or sv.size > 0) then
            {sleep .2s} || something heavy calculation
            {if sv == "ok" then
                {return null}
            }
            {return "Invalid input: " & target.value-as-any}
        }
        }
    }
  {return null}
  }
}

{let D4:Dialog = 
    {Dialog
        margin = 9pt,
        message-display = {MultiMessageDialog},
        {validate-with {DialogValidator}},
        {spaced-vbox
            {text
                Buttons always enabled, give messages when you click button
                and when edit finished
                {br}dialog-on-finished?=true
                {br}don't check d.valid?
            },

            {TextField 
                value = "d",
                {validate-with {MyValidator}, required? = false,
                    dialog-on-finished? = true, refocus? = true
                }
            },
            {TextField 
                value = "3",
                {validate-with {MyValidator}, required? = false,
                    dialog-on-finished? = true, refocus? = true
                }
            },
            {CommandButton
                label = "&OK",
                {on Action at cb:CommandButton do
                    {if-non-null d = cb.dialog then
                        {if {validate-dialog d} then
                            {popup-message "OK"}
                        }
                    }
                }
            },
            {CommandButton
                label = "&Help",
                {on Action at cb:CommandButton do
                    {popup-message "Help!"}
                }
            }

        }
    }
}

{CommandButton
    label = "&4. Check Always",
    width = 1.5in,
    {on Action do
        {D4.show title = "Validate on Button"}
    }
} Check on button and on entry finished