Do you really want each record with a checked CheckButton to be part of the RecordGridSelection? Selection is affected by a number of other processes, and you would need to make changes to the UI's event handling code to ensure that the user could not affect the Selection other than by your intended means.

If alternatively you only need to mark records and not via a Selection, then that's much easier; e.g. see row-background-spec. Depending on your other desired functionality, you might then be able to turn off selection entirely -- though Selection can also coexist with this technique -- and use only your boolean state + row styling for whatever bulk operations you might provide.

I think the best way to do this is to not use the built in record selection mechanism at all. Instead, use a boolean field in each record to indicate if the record is selected. Use a custom column header to get the select-all checkbutton at the top, and use a row-background-spec procedure to colorize the selected records. Here is some sample code:

{curl 6.0, 7.0 applet}
{title Checkbox in Header}

{import * from CURL.DATA-ACCESS.BASE}

{let dataset:RecordSet = 
    {RecordSet
        {RecordFields
            {RecordField "id", 
                caption = "ID", domain = int,
                index-type = RecordFieldIndexType.unique
            },
            {RecordField "Title", domain = String},
            {RecordField "Date", domain = {StandardDateDomain}},
            {RecordField "selected", caption = "\u221a", domain = bool}
        },
        {RecordData id = 1, Title = "Meeting Friday", Date = "2007-12-15"},
        {RecordData id = 2, Title = "Re: Meeting Friday", Date = "2007-12-16"},
        {RecordData id = 3, Title = "Re: Meeting Friday", Date = "2007-12-16"},
        {RecordData id = 4, 
            Title = "Need your help (financial transaction)",
            Date = "2008-04-01"
        },
        {RecordData id = 5, Title = "Good news", Date = "2008-05-05"}
    }
}

{let select-all-ctrl:CheckButton = 
    {CheckButton
        label = "",
        {on ValueChanged at cb:CheckButton do
            {with rg.records.batch-events? = true do
                {for r:Record key ri:int in rg.records do
                    set r["selected"] = cb.value
                }
            }
        }
    }
}

{let rg:RecordGrid = 
        {RecordGrid 
            width = 5in, height = 3in,
            background = "#f0f0f0",
            display-filler-column? = true,
            display-record-selectors? = false,
            display-navigation-panel? = false,
            record-source = dataset,
            editable? = true,
            select-current-record? = false,
            row-background-spec = 
                {proc {rg:RecordGrid, r:Record, ri:int}:#Background
                    {return 
                        {if r["selected"] asa bool then
                            "#ffff0080" 
                         else
                            null
                        }
                    }
                },
            automatic-columns? = false,
            {RecordGridColumn  width = 18pt, "selected", 
                header-spec = select-all-ctrl,
                halign = "center"
            },
            {RecordGridColumn  width = 3.5in, "Title"},
            {RecordGridColumn  width = 60pt, "Date"}
        }
}

{do
    {rg.records.add-event-handler
        {on RecordModified at rv:RecordView do
            let all?:bool = true
            {for r:Record key ri:int in rg.records do
                {if not rg.records[ri]["selected"] asa bool then
                    set all? = false
                    {break}
                }
            }
            set select-all-ctrl.value = all?
        }
    }
}

{value rg}

The code I posted does give you a check button at the left of each record at the left. It looks a lot like the image you referenced. Please explain in greater detail the additional functionality you'd like to see.

In my example code, I'm not using the built-in selection mechanism. I'm using the data model (the recordset) to represent the "selected" records. I believe it works the way you want it to for items (1) through (4). I'm not sure what you mean by item (5). It may be that the image doesn't look selected, even though it is part of a selected row. In my scheme, the yellow highlighting is applied to the row background, so it won't be seen if the image is opaque. You could add some margin to the image so that the background is at least visible in the margin.

It sounds like you are still using the selection mechanism in your code. That would explain (6).