{curl 7.0 applet}
 
Using SkinnableDropdownListUI (easier):
 
{define-class public open SkinnableBallooningDDLUI
  {inherits SkinnableDropdownListUI}
 
  {constructor public {default
                          control:#DropdownList = null,
                          control-skin:DropdownListSkin = {DropdownListSkin},
                          control-feel:DropdownListFeel = {DropdownListFeel},
                          ...
                      }
    {construct-super
        control = control,
        control-skin = control-skin,
        control-feel = control-feel,
        ...
    }
  }
 
  {method public open {show-dropdown}:void
    {type-switch self.control
     case ddl:DropdownList do
        || >>>> Insert any special handling here:
        {ddl.append "One More"}
        || <<<<
    }
    {super.show-dropdown}
  }
 
}
 
{let sample-list-1:DefaultListModel =
    {DefaultListModel
        "One",
        "Two",
        "Three"
    }
}
 
{DropdownList
    prompt = "Choose a state:",
    data-model = sample-list-1,
    dropdown-height = 2in,
    ui-object =
        {SkinnableBallooningDDLUI
            control-skin = {SkinnedDropdownListSkin},
            control-feel =
                {platform-switch
                 case "mac" do
                    {AquaDropdownListFeel}
                 else
                    {SkinnedDropdownListFeel}
                }
        }
}
 
Using StandardDropdownListUI (harder):
 
{define-class public open StandardBallooningDDLUI
  {inherits StandardDropdownListUI}
 
  field private _last-search-time:#DateTime
  field private _search-buf:#StringBuf
 
  {constructor public {default
                          control:#DropdownList = null,
                          ...
                      }
    {construct-super
        control = control,
        ...
    }
  }
 
  {getter private {last-search-time}:DateTime
    {return
        {if-non-null dt = self._last-search-time then
            dt
         else
            def dt = {DateTime}
            set self._last-search-time = dt
            dt
        }
    }
  }
 
  {getter private {search-buf}:StringBuf
    {return
        {if-non-null buf = self._search-buf then
            buf
         else
            def buf = {StringBuf}
            set self._search-buf = buf
            buf
        }
    }
  }
 
  {method protected open {create-dropdown-helper}:StandardDropdownHelper
    def helper = {BallooningDropdownHelper self}
    || Unfortunately, the original event handler we would like to
    || attach here is not public, so we inline a copy from open controls.
    {helper.menu.add-event-handler
        {on e:KeyPress do
            {self.process-menu-event e}
        }
    }
    {return helper}
  }
 
  {method private {process-menu-event e:KeyPress}:void
    {if e.insertable? then
        || Get the current selected index.
        def menu = self.dropdown-helper.menu
        let current-selected:int = -1
        {for i = 0 below menu.size do
            {type-switch menu[i]
             case mi:MenuItem do
                {if mi.item-active? then
                    set current-selected = i
                    {break}
                }
            }
        }
        def index = {self.get-index-for-selection e.value, current-selected}
        {if index != -1 then
            def ddl = self.control asa DropdownList
            def item = ddl[index]
            {if-non-null menu-action = 
                {item.find-ancestor 
                    {proc {g:Graphic}:bool {return g isa MenuAction}}
                } asa #MenuAction
             then
                {menu-action.become-active-item}
            }                
        }
    }
 
  }
 
  {method private {get-index-for-selection 
                      c:char,
                      current-index:int
                  }:int
    def ddl = self.control asa DropdownList
    let size:int = ddl.for-loop-count
    def last-search-time = self.last-search-time
    def search-buf = self.search-buf
 
    def reset?:bool = {last-search-time.elapsed} > 0.5s
 
    def sel-index = 
        {if reset? then
            {max current-index + 1, 0}
         else
            {max current-index, 0}
        }
 
    {if reset? then
        {search-buf.clear}
    }
    {search-buf.append c}
    set self._last-search-time = {DateTime}
 
    {for i:int = 0 below size do
        let index:int = (i+sel-index) mod size
        {if ddl[index].selectable? then
            {type-switch ddl[index].value 
             case str:StringInterface do
                {if not str.empty? then
                    {if {str.prefix? search-buf, ignore-case? = true} then
                        {return index}
                    }
                }
             case ch:char do
                {if {char-downcase ch} == {char-downcase c} then
                    {return index}
                }
            }
        }
    }
 
    || Make sure that if some one is searching for the same character
    || quickly and we added it to our list then collapse and search
    || again.
    {if search-buf.size == 2 and 
        search-buf[0] == search-buf[1]
     then
        {search-buf.remove 1}
    }   
 
    {for i:int = 0 below size do
        let index:int = (i+sel-index + 1) mod size
        {if ddl[index].selectable? then
            {type-switch ddl[index].value 
             case str:StringInterface do
                {if not str.empty? then
                    {if {str.prefix? search-buf, ignore-case? = true} then
                        {return index}
                    }
                }
             case ch:char do
                {if {char-downcase ch} == {char-downcase c} then
                    {return index}
                }
            }
        }
    }
 
    {return -1}
  }
 
}
 
{define-class public open BallooningDropdownHelper
  {inherits StandardDropdownHelper}
 
  {constructor public {default owner:StandardBaseDropdownUI}
    {construct-super owner}
  }
 
  {method public open {show-dropdown}:void
    {type-switch (self.owner asa ControlUI).control
     case ddl:DropdownList do
        || >>>> Insert any special handling here:
        {ddl.append "One More"}
        || <<<<
    }
    {super.show-dropdown}    
  }
 
}
 
 
{let sample-list-2:DefaultListModel =
    {DefaultListModel
        "One",
        "Two",
        "Three"
    }
}
 
{DropdownList
    prompt = "Choose a state:",
    data-model = sample-list-2,
    dropdown-height = 2in,
    ui-object = {StandardBallooningDDLUI}
}