Since you need different Views for you calendar control you may choose to have one of the following Approach.
1. Write your own calendar control UI and depending on a flag to that UI, you show the day, week, month view.
2. Better, you may have three different subclasses of the UI. You can then create 3 Calendar Control's and each one of them uses its own custom UI. Make sure that the three calendar controls use the same data model.
3. As in step 2, you may have three different UI's. However you have one CalendarControl. You can then set the UI for the CalendarControl of your choice. You can always switch a CalendarControlUI with another one.
Kindly see my response to "Regarding Calendarcontrol". Here I have shown how to write your custom UI. You will also find an example in the Curl help for StandardCalendarControlUI.create-main-panel.
Now the question is how you can write something where you can drag-select a bunch of rows, each one of them corresponding to 1 hour of th time. You may use a Canvas for this UI. This canvas you may arrange a number of Frames, each representing a row (if each row represents an hour, you will have 24 of these). You may listen for "PointerPress", "DragStarted" and PointerRelease and "GrabRelease messages.
Here is some code that shows you how you can use the above mentioned messages to identify which rows where selected. Note that this is just an example to develop your ides on.
{curl 6.0, 7.0 applet}
{curl-file-attributes character-encoding = "windows-latin-1"}
{define-class public CustomFrame {inherits Frame}
field public constant index:int
{constructor public {default index:int, ...}
set self.index = index
{construct-super height = .5cm, width = 1in, ...}
}
}
{define-class public CustomVBox {inherits VBox}
field private dragging?:bool
field private start-index:int
{constructor public {default ...}
|| Setting opaque-to-events? to true makes sure that this box will get the
|| pointer events, even if it has a transparent background or no border.
{construct-super opaque-to-events? = true, ...}
}
{method private {get-cutom-frame-at x:Distance, y:Distance}:int
def cf =
{self.find-graphic-at
x, y,
{proc {g:Graphic}:bool
{return g isa CustomFrame}
}
} asa #CustomFrame
{return
{if-non-null cf then
cf.index
else
-1
}
}
}
{method public {on-pointer-press e:PointerPress}:void
{if e.state-mask.button-1? then
set self.start-index = {self.get-cutom-frame-at e.x, e.y}
{if self.start-index != -1 then
|| Grab the pointer so that all the pointer events are sent to this
|| box. Note that since this is an implicit grab, the grab will be
|| in effect till the Pointer is released or the Grab ends because
|| of say the View to which this Box belongs looses focus.
{e.continue-implicit-pointer-grab self}
|| Consume the event to make sure that the Boxes parent
|| does not see it. Otherwise, the grab may end for this box
|| if the parent decides to grab the pointer.
{e.consume}
}
}
{super.on-pointer-press e}
}
{method public {on-drag-started e:DragStarted}:void
{if self.start-index != -1 then
set self.dragging? = true
{e.consume}
}
{super.on-drag-started e}
}
{method public {on-pointer-release e:PointerRelease}:void
def dragging? = self.dragging?
set self.dragging? = false
{if dragging? then
{e.consume}
def end-index = {self.get-cutom-frame-at e.x, e.y}
{if end-index != -1 then
{popup-message
"Selected from: " & self.start-index & " to: " & end-index
}
}
set self.start-index = -1
}
{super.on-pointer-release e}
}
{method public {on-grab-release e:GrabRelease}:void
set self.dragging? = false
set self.start-index = -1
{e.consume}
{super.on-grab-release e}
}
{method public {add-row index:int, ...}:void
{self.add
{CustomFrame index, ...}
}
}
}
{value
def vb = {CustomVBox}
{vb.add-row 1, background = "lime"}
{vb.add-row 2, background = "red"}
{vb.add-row 3, background = "pink"}
vb
}
Message was edited by: Kamal
