Here's an example with both a click handler that traverses and a key handler that jumps.

Click on cb2 (or press space when it has focus) and cb1 will become active. This happens by asking cb2 what active traversal container it is in, then asking that container to make the "previous" traversor active, just like when pressing shift-tab. cb2 doesn't know who is previous, it is asking the container to do the work and pick someone. The way it's written here, this will happen regardless of whether it's cb2 that has the focus, so if you uncomment the takes-focus? line, clicking on the button will actually toggle the active control between the two others, since cb2 will opt not to take part in its container's traversal.

Press ctrl+shift+m at cb1 when it has focus and tf will become active. This happens by directly asking the TextField to become the active control for its container.

Note the "after 0s" which politely queues the navigation rather than immediately forcing it.

{def tf = {TextField}}
 
{def cb1 =
    {CommandButton
        {on e:KeyPress at cb:CommandButton do
            {if not e.consumed? and
                {e.modifiers-match? shift? = true, ctrl? = true} and
                e.value == 'M' or e.value == 'm'
             then
                {after 0s do
                    {tf.become-active}
                }
                {e.consume}
            }
        }
    }
}
 
{def cb2 =
    {CommandButton
||--        takes-focus? = false,
        {on Action at cb:CommandButton do
            {after 0s do
                {if-non-null atc = cb.active-traversal-container then
                    {atc.traverse forward? = false}
                }
            }
        }
    }
}
 
{spaced-vbox tf, cb1, cb2}