It's certainly possible to add DnD to RecordGrid, but it could be a difficult project to fit that in appropriately among all the existing gesture handling. Certainly one could take the OPEN-CONTROLS code and modify it extensively to support the desired operations.

If you are looking for more limited support, you could do something along the lines of the following example, where I've made individual cells dragable. Note that to vastly simplify things, I've turned off cells taking focus, since otherwise clicking on a cell to drag it would likely remove the selection that you were trying to drag. You sadly cannot drag from the row selector in the example either -- that would require OPEN-CONTROLS modification since the row selector is not a publicly accessible element. You could also spruce this example up with a better ImageDragee graphic, etc., but I've omitted all that to keep this manageable. As a general warning, you'd really never want to actually move any Graphics that you drag out of the Ul; rather, if you wanted to "drag out" Records, you should use RecordSet operations to indirectly do so.

In the example, dragging a cell, or a cell from a set of selected rows, will add the "First" data from those Record(s) to the VBox.

{let people:RecordSet =
    {RecordSet
        {RecordFields
            {RecordField "First", domain = String},
            {RecordField "Last", domain = String},
            {RecordField "Age", domain = int}
        },
        {RecordData First = "John", Last = "Smith", Age = 25},
        {RecordData First = "Jane", Last = "Smith", Age = 29},
        {RecordData First = "Jane", Last = "Jones", Age = 28}
    }
}
 
{define-class public open DragStringCell {inherits StandardStringCell}
 
  {constructor public {default}
    {construct-super}
    set self.dragee = {ImageDragee}
  }
 
}
 
{let rg:RecordGrid =
    {RecordGrid
        record-source = people,
        height = 3cm,
        display-column-headers? = false,
        display-filler-column? = true,
        alternate-row-background = "#cceecc",
        grid-line-color = "#ccccff",
        horizontal-grid-line-width = 2px,
        vertical-grid-line-width = 4px,
        cell-spec = DragStringCell,
        cells-take-focus? = false
    }
 
}
 
{value rg}
 
{define-proc package {drop-action
                         vb:VBox,
                         a:any
                     }:{proc-type {}:void}
    {return
        {proc {}:void
            {type-switch a
             case dsc:DragStringCell do
                {vb.clear}
                {if-non-null grid = dsc.grid then
                    def selection = grid.selection
                    let passed-selection?:bool = false
                    {if selection.record-count >= 1 then
                        {if {selection.contains-record? dsc.record-index} then
                            set passed-selection? = true
                            {for one-record in grid.selection.records do
                                {vb.add grid.records[one-record]["First"]}
                            }
                        }
                    }
                    {if not passed-selection? then
                        {vb.add dsc.record["First"]}
                    }
                }
            }
        }
    }
}
 
{value
    def vb =
        {VBox
            margin = 5mm,
            border-color = "red",
            border-width = 2px,
            opaque-to-events? = true
        }
 
    {vb.add-event-handler
        {on e:DragOver do 
            {e.will-accept-drop?
                {proc {type:Type, x:Distance, y:Distance,
                       effect:#DragEffect}:DragEffect
                    {if type == DragStringCell then
                        {return drag-effect-copy}
                     else
                        {return drag-effect-none}
                    }
                }
            }
        }
    }
    
    {vb.add-event-handler
        {on e:Drop at vb:VBox do
            {e.accept-drop
                {proc {a:any, x:Distance, y:Distance,
                       effect:#DragEffect}:DropResult
                    {return
                        {DropResultCopy
                            action = {drop-action vb, a}
                        }
                    }
                }
            }
        }
    }
    
    vb
}