{import * from CURL.GUI.EMBEDDED-BROWSER}
{def eb =
    {try
        {EmbeddedBrowserGraphic}
     catch ex:Exception do
        null
    }
}
{VBox
    {HBox
        enabled? = (eb != null),
        {CommandButton
            label="<-",
            {on Action do
                {eb.browse-backward}
            }
        },
        {CommandButton
            label="->",
            {on Action do
                {eb.browse-forward}
            }
        },
        {CommandButton
            label="Reload",
            {on Action do
                {eb.browser-refresh force-reload? = true}
            }
        },
        {CommandButton
            label="Stop",
            {on Action do
                {eb.browser-stop}
            }
        },
        {TextField
            {on Action at tf:TextField do
                {try
                    {eb.browse-url
                        {parse-url (tf.value asa String)}
                    }
                 catch ex:Exception do
                    {popup-message ex.message}
                }
            }
        },
        {CommandButton
            label="+",
            {on Action do
                {eb.browser-zoom-in}
            }
        },
        {CommandButton
            label="-",
            {on Action do
                {eb.browser-zoom-out}
            }
        }
    },
    {if-non-null eb then
        eb
     else
        {paragraph
            EmbeddedBrowserGraphic is not supported on this platform.
        }
    }
}